DATUM in Excel: zo gebruik je het
Engels: DATE
DATUM maakt een echte datum uit een jaar, een maand en een dag. De volgorde is altijd jaar, maand, dag.
Probeer gratis de eerste oefeningenIn de les VANDAAG en DATUM
Wat doet DATUM?
DATUM maakt een echte datum uit drie getallen: het jaar, de maand en de dag, altijd in die volgorde. Zo'n datum kan Excel tonen in de notatie van je land, en je kunt ermee rekenen.
Dat is handig als jaar, maand en dag in aparte kolommen staan, of als je een datum in een formule nodig hebt: =DATUM(2026;12;31) is overal eenduidig, terwijl een getypte datum tussen aanhalingstekens afhangt van de landinstellingen.
Wanneer gebruik je DATUM?
- Jaar, maand en dag uit drie kolommen samenvoegen tot één datum: =DATUM(A2;B2;C2).
- De eerste dag van de maand van een datum: =DATUM(JAAR(A2);MAAND(A2);1).
- Een vaste datum in een formule, zoals een deadline: =DATUM(2026;12;31)-VANDAAG().
- Dezelfde dag drie maanden later, bijvoorbeeld het einde van een proefperiode: =ZELFDE.DAG(A2;3).
Syntax
De syntax is het vaste patroon van een functie. De woorden tussen de haakjes zijn plaatshouders: daar vul je zelf iets in, zoals een cel, een getal of een tekst. Al de rest typ je precies zoals het er staat.
Een echte datum uit een jaar, een maand en een dag.
Ingevuld: =DATUM(A2;B2;C2)
Zo lees je de formule, onderdeel per onderdeel:
| Onderdeel | Wat het betekent | In het voorbeeld |
|---|---|---|
= | Elke formule begint met een gelijkheidsteken. Zonder = ziet Excel wat je typt als gewone tekst. | = |
DATUM | De naam van de functie: zo weet Excel wat het moet doen. Je mag ze in kleine letters typen, Excel zet ze zelf in hoofdletters. | DATUM |
( ) | Meteen na de naam komen de haakjes. Daartussen staat wat de functie nodig heeft om te werken: de argumenten. | ( ) |
jaar | Het jaartal, met vier cijfers. | A2 |
maand | Het nummer van de maand. Een getal boven 12 loopt door naar het volgende jaar. | B2 |
dag | Het nummer van de dag. | C2 |
; | Een puntkomma scheidt de argumenten van elkaar. In een Engelstalige Excel is dat een komma. | ; |
DATUM stap voor stap
In D2 staat =DATUM(A2;B2;C2). DATUM maakt van de drie getallen één echte datum. Pas de cijfers of de formule aan en kijk wat er gebeurt.
Zo bouw je die formule zelf op:
- Klik in D2 en typ DATUM met een haakje.
=DATUM( - Klik op het jaar in A2 en typ een puntkomma. Het jaar komt altijd eerst.
=DATUM(A2; - Klik op de maand in B2, typ een puntkomma en klik op de dag in C2.
=DATUM(A2;B2;C2 - Sluit het haakje en druk op Enter: je krijgt de datum 21 juli 2026.
=DATUM(A2;B2;C2)
Meer voorbeelden
De eerste van de maand
In C1 staat =DATUM(JAAR(A2);MAAND(A2);1). JAAR en MAAND halen het jaar en de maand uit A2, en de dag wordt 1.
Een maand die doorloopt
In C2 staat =DATUM(A2;B2;1). Maand 14 bestaat niet, dus Excel loopt door: 1 februari 2027. Zo reken je makkelijk met maanden.
Drie maanden later met ZELFDE.DAG
In C1 staat =ZELFDE.DAG(A2;3). 31 april bestaat niet, dus ZELFDE.DAG geeft de laatste dag van april: 30 april.
Rekenen met overlopende waarden
=DATUM(2026;13;1) geeft 1 januari 2027. Excel loopt netjes door, en dat maakt rekenen met maanden eenvoudig.
Een datum uit elkaar halen
=JAAR(A1), =MAAND(A1) en =DAG(A1) halen elk een deel uit een datum. =WEEKDAG(A1;2) geeft de dag van de week met maandag als 1, en =ISO.WEEKNUMMER(A1) het weeknummer zoals in onze agenda.
Een datum is een getal
Voor Excel is 1 maart 2026 het getal 46082: het aantal dagen sinds 1900. Daarom geeft =B2-A2 het aantal dagen tussen twee datums, en =A2+30 de datum 30 dagen later.
Hier gaat het vaak mis
- Een datum in een formule typen als "01/03/2026" hangt af van de landinstellingen. DATUM is altijd eenduidig.
- Zie je na =MAAND(A1) een datum zoals 1/1/1900, dan staat de cel nog in datumopmaak. Zet ze op Standaard.
Oefen dit in de les VANDAAG en DATUM, met correctie en uitleg bij elke stap. De eerste oefeningen zijn gratis.
Veelgestelde vragen
Hoe voeg ik maanden toe?
Met ZELFDE.DAG: =ZELFDE.DAG(A1;3) geeft dezelfde dag drie maanden later. Bestaat die dag niet, zoals 31 april, dan krijg je de laatste dag van de maand.
Hoe vind ik het kwartaal van een datum?
Met =AFRONDEN.NAAR.BOVEN(MAAND(A1)/3;0): maand 1 tot 3 geeft 1, maand 4 tot 6 geeft 2, enzovoort.
Lees ook
JAAR, MAAND en DAGVANDAAGDATUMVERSCHILNETTO.WERKDAGEN en WERKDAGRekenen met tijd