INDEX en VERGELIJKEN in Excel: zo gebruik je het
Engels: INDEX, MATCH
VERGELIJKEN vertelt op welke plaats iets staat, en INDEX haalt op wat op die plaats staat. Samen zoeken ze in elke richting, en dat in elke Excel-versie.
Probeer gratis de eerste oefeningenIn de les INDEX en VERGELIJKEN
Wat doen INDEX en VERGELIJKEN?
VERGELIJKEN zoekt een waarde in een kolom en vertelt op welke plaats ze staat: de eerste, de tweede, de derde. INDEX doet het omgekeerde: je geeft een plaats op, en het haalt op wat daar staat.
Samen zoeken ze iets op, zoals VERT.ZOEKEN, maar flexibeler: de kolom met het antwoord mag overal staan, ook links, en een extra kolom in je tabel brengt de formule niet in de war. Ze werken in elke versie van Excel.
Wanneer gebruik je INDEX en VERGELIJKEN?
- De prijs bij een productnaam: =INDEX(C2:C50;VERGELIJKEN(E2;B2:B50;0)).
- Naar links zoeken, zoals de code bij een naam: =INDEX(A2:A50;VERGELIJKEN(E2;B2:B50;0)).
- De naam bij de hoogste omzet: =INDEX(A2:A50;VERGELIJKEN(MAX(C2:C50);C2:C50;0)).
- Een waarde uit een tabel met rijen en kolommen, zoals product en maand: met VERGELIJKEN voor de rij én voor de kolom.
Syntax
De syntax is het vaste patroon van een functie. De woorden tussen de haakjes zijn plaatshouders: daar vul je zelf iets in, zoals een cel, een getal of een tekst. Al de rest typ je precies zoals het er staat.
Wat op de zoveelste plaats in een kolom staat.
Ingevuld: =INDEX(C2:C5;3)
Zo lees je de formule, onderdeel per onderdeel:
| Onderdeel | Wat het betekent | In het voorbeeld |
|---|---|---|
= | Elke formule begint met een gelijkheidsteken. Zonder = ziet Excel wat je typt als gewone tekst. | = |
INDEX | De naam van de functie: zo weet Excel wat het moet doen. Je mag ze in kleine letters typen, Excel zet ze zelf in hoofdletters. | INDEX |
( ) | Meteen na de naam komen de haakjes. Daartussen staat wat de functie nodig heeft om te werken: de argumenten. | ( ) |
matrix | Bij INDEX: de kolom waaruit je het antwoord haalt. | C2:C5 |
rij_getal | Bij INDEX: op welke plaats het antwoord staat. Dat getal komt van VERGELIJKEN. | 3 |
; | Een puntkomma scheidt de argumenten van elkaar. In een Engelstalige Excel is dat een komma. | ; |
INDEX en VERGELIJKEN stap voor stap
In E1 staat =INDEX(C2:C5;VERGELIJKEN("Monitor";B2:B5;0)). VERGELIJKEN geeft 3, en INDEX leest de derde prijs. Pas de cijfers of de formule aan en kijk wat er gebeurt.
Zo bouw je die formule zelf op:
- Begin met het binnenste stuk. Typ in E1 VERGELIJKEN met wat je zoekt en waar: "Monitor" in de productnamen B2:B5, en 0 voor exact zoeken.
=VERGELIJKEN("Monitor";B2:B5;0) - Druk gerust even op Enter: je krijgt 3, want Monitor staat op de derde plaats. Klik daarna terug in de formule.
- Zet INDEX ervoor: na het gelijkheidsteken INDEX met een haakje, de kolom met het antwoord, C2:C5, en een puntkomma.
=INDEX(C2:C5;VERGELIJKEN("Monitor";B2:B5;0) - Sluit het laatste haakje en druk op Enter: INDEX leest de derde prijs, 219.
=INDEX(C2:C5;VERGELIJKEN("Monitor";B2:B5;0))
Meer voorbeelden
Naar links zoeken
In E1 staat =INDEX(A2:A5;VERGELIJKEN("Bureau";B2:B5;0)). De code staat links van de productnaam. Met VERT.ZOEKEN lukt dat niet, met INDEX en VERGELIJKEN wel.
De naam bij de hoogste omzet
In E1 staat =INDEX(A2:A6;VERGELIJKEN(MAX(C2:C6);C2:C6;0)). MAX vindt 1200, VERGELIJKEN zegt dat dat op plaats 1 staat, en INDEX geeft de regio op die plaats: Gent.
Rij en kolom tegelijk
In D6 staat =INDEX(B2:D4;VERGELIJKEN(B6;A2:A4;0);VERGELIJKEN(B7;B1:D1;0)). De eerste VERGELIJKEN zoekt de rij van Scherm, de tweede de kolom van Feb. INDEX haalt op wat op het kruispunt staat: 28.
Waarom nog gebruiken?
Ook in een oude Excel doet ze het, en een extra kolom in je tabel brengt ze niet in de war. In sollicitatietests voor financiële functies komt ze ook regelmatig terug.
Naar links zoeken
De resultaatkolom mag links van de zoekkolom staan. Zoek je de code bij een productnaam en staat de code vooraan, dan schrijf je =INDEX(A2:A5;VERGELIJKEN(E2;B2:B5;0)). Met VERT.ZOEKEN lukt dat niet.
Zoeken op rij en kolom tegelijk
Heb je een tabel met producten in de rijen en maanden in de kolommen, gebruik VERGELIJKEN dan twee keer: =INDEX(B2:E5;VERGELIJKEN(G1;A2:A5;0);VERGELIJKEN(G2;B1:E1;0)). De eerste zoekt de rij, de tweede de kolom.
Hier gaat het vaak mis
- Vergeet de 0 in VERGELIJKEN niet, anders zoek je niet exact.
Oefen dit in de les INDEX en VERGELIJKEN, met correctie en uitleg bij elke stap. De eerste oefeningen zijn gratis.
Veelgestelde vragen
Is X.ZOEKEN beter?
Het is eenvoudiger, maar werkt niet in oudere versies. Ken dus allebei.