X.ZOEKEN in Excel: zo gebruik je het
Engels: XLOOKUP
Met X.ZOEKEN wijs je aan waar Excel moet zoeken en waar het antwoord staat. Het werkt in beide richtingen en zoekt standaard exact. Je hebt wel Excel 2021 of 365 nodig.
Probeer gratis de eerste oefeningenIn de les Opzoeken met X.ZOEKEN
Wat doet X.ZOEKEN?
X.ZOEKEN zoekt een waarde in één kolom en geeft wat op dezelfde rij in een andere kolom staat. Je wijst gewoon de twee kolommen aan: waar Excel moet zoeken, en waar het antwoord staat.
Je hoeft dus geen kolommen te tellen, het antwoord mag links of rechts van de zoekkolom staan, en X.ZOEKEN zoekt standaard exact. Met het vierde argument geef je meteen een eigen melding op als de waarde niet gevonden wordt.
Wanneer gebruik je X.ZOEKEN?
- De prijs bij een code: =X.ZOEKEN(E2;A2:A50;C2:C50).
- De code bij een productnaam, dus naar links: =X.ZOEKEN(E2;B2:B50;A2:A50).
- Een eigen melding als iets ontbreekt: =X.ZOEKEN(E2;A2:A50;C2:C50;"Onbekend").
- De korting bij een bedrag dat tussen twee grenzen valt: =X.ZOEKEN(B2;F2:F5;G2:G5;0;-1).
Syntax
De syntax is het vaste patroon van een functie. De woorden tussen de haakjes zijn plaatshouders: daar vul je zelf iets in, zoals een cel, een getal of een tekst. Al de rest typ je precies zoals het er staat.
Ingevuld: =X.ZOEKEN("Monitor";B2:B5;A2:A5;"Onbekend")
Zo lees je de formule, onderdeel per onderdeel:
| Onderdeel | Wat het betekent | In het voorbeeld |
|---|---|---|
= | Elke formule begint met een gelijkheidsteken. Zonder = ziet Excel wat je typt als gewone tekst. | = |
X.ZOEKEN | De naam van de functie: zo weet Excel wat het moet doen. Je mag ze in kleine letters typen, Excel zet ze zelf in hoofdletters. | X.ZOEKEN |
( ) | Meteen na de naam komen de haakjes. Daartussen staat wat de functie nodig heeft om te werken: de argumenten. | ( ) |
zoekwaarde | Wat je zoekt. | "Monitor" |
zoekmatrix | De kolom of rij waarin je zoekt. | B2:B5 |
retourmatrix | De kolom of rij met het antwoord. | A2:A5 |
[indien_niet_gevonden] | Niet verplicht: wat je wilt zien als de waarde er niet in staat. | "Onbekend" |
[overeenkomst] | Niet verplicht: 0 voor exact zoeken (standaard), -1 voor de eerstvolgende lagere en 1 voor de eerstvolgende hogere waarde. | weggelaten |
[zoekmodus] | Niet verplicht: -1 om onderaan te beginnen. | weggelaten |
; | Een puntkomma scheidt de argumenten van elkaar. In een Engelstalige Excel is dat een komma. | ; |
" " | Tekst typ je tussen aanhalingstekens, zoals "Gent". Een getal of een cel, zoals 500 of A2, typ je zonder. | |
[ ] | Wat tussen rechte haken staat, mag je weglaten. De haken zelf typ je nooit. |
X.ZOEKEN stap voor stap
In E1 staat =X.ZOEKEN("Monitor";B2:B5;A2:A5;"Onbekend"). Zoekt naar links, en dat kan VERT.ZOEKEN niet. Pas de cijfers of de formule aan en kijk wat er gebeurt.
Zo bouw je die formule zelf op:
- Typ in E1 de functie met een haakje.
=X.ZOEKEN( - Typ wat je zoekt: "Monitor". Typ een puntkomma.
=X.ZOEKEN("Monitor"; - Selecteer waar Excel moet zoeken: de productnamen in B2:B5. Typ een puntkomma.
=X.ZOEKEN("Monitor";B2:B5; - Selecteer waar het antwoord staat: de codes in A2:A5. Die kolom mag links van de zoekkolom staan.
=X.ZOEKEN("Monitor";B2:B5;A2:A5 - Typ een puntkomma en een melding voor als het product niet bestaat: "Onbekend". Sluit het haakje en druk op Enter: P-204.
=X.ZOEKEN("Monitor";B2:B5;A2:A5;"Onbekend")
Meer voorbeelden
De prijs bij een code
In E1 staat =X.ZOEKEN("P-102";A2:A5;C2:C5). Zoeken in de codes, het antwoord uit de prijzen. Een kolomnummer heb je niet nodig.
Een eigen melding
In E1 staat =X.ZOEKEN("P-999";A2:A5;C2:C5;"Onbekend"). De code bestaat niet. In plaats van #N/B zie je de melding uit het vierde argument.
De eerstvolgende lagere waarde
In D1 staat =X.ZOEKEN(750;A2:A4;B2:B4;0;-1). Met -1 als vijfde argument neemt Excel de eerstvolgende lagere waarde als 750 er niet staat: 500, dus 5% korting.
De voordelen
Geen kolomnummers meer tellen, zoeken in elke richting en een eigen melding als iets niet gevonden wordt. Met -1 als zesde argument begint Excel onderaan, handig als je de laatste boeking wilt.
X.ZOEKEN of VERT.ZOEKEN?
X.ZOEKEN zoekt standaard exact, kijkt ook naar links en loopt niet stuk als je een kolom toevoegt, want je telt geen kolommen. Gebruikt iemand een oudere Excel dan 2021, dan krijgt die #NAAM? te zien. Deel je bestanden met veel mensen, dan blijft VERT.ZOEKEN of INDEX met VERGELIJKEN de veiligste keuze.
Meerdere kolommen tegelijk ophalen
Selecteer je als antwoord meerdere kolommen, zoals =X.ZOEKEN(E2;A2:A5;B2:C5), dan vult Excel de cellen ernaast vanzelf in met product en prijs. Die cellen moeten wel leeg zijn, anders krijg je #OVERLOOP!.
Hier gaat het vaak mis
- Werkt niet in Excel 2019 of ouder.
- De zoek- en retourmatrix moeten even groot zijn.
Oefen dit in de les Opzoeken met X.ZOEKEN, met correctie en uitleg bij elke stap. De eerste oefeningen zijn gratis.
Veelgestelde vragen
Hoe zoek ik de dichtstbijzijnde waarde?
Geef als vijfde argument -1 voor de eerstvolgende lagere of 1 voor de eerstvolgende hogere waarde.